Ezaguna denez, Azterketa: 2024ko maiatzaren deialdia izenburuko artikuluan azterkari buruzko informazio guzti-guztia dago. Heltzear den uztaileko deialdiari dagokion programa prestatze aldera, berridatz dezagun maiatzeko programa hori, baina derrigorrezko aginduak nabarmenduz (letra larrietan idatzirik ematen diren aginduak). Ez dugu esan nahi gainerako aginduak soberan daudenik, baizik eta letra larrietan idatziko ditugunak berebiziko garrantzia dutela eta besteak horien menpekoak direla nolabait.
Maiatzeko programan bi datu-fitxategiekin lan egiten da MAHAIAK.DAT dat-fitxategia eta MENUAK.DAT datu-fitxategia. Bi datu-fitxategi horiek aldez aurretik sortuta daude JatetxekoDatuakSortzen.pas programari esker.
2024-05-22_Jatetxea_DerrigorrezkoAginduak.pas fitxategian jasota dagoen maiatzeko programa berezian, letra larriz nabarmendu dira ezinbestekoak diren aginduak. Konpiladorearen ingurune barnetik programa hau exekutatzean, MAHAIAK.DAT datu-fitxategia eta MENUAK.DAT datu-fitxategia C:\Dev-Pas karpetan kokatu behar dira nahitaez. Maiatzeko programa bereziaren kodea jarraian ikusi, non, aurreratu den bezala, azpiprograma bakoitzean letra larrietan jarri diren aginduak garrantzitsutzat jo daitezkeen:
{ Hitz larrietan idatzi diren aginduak funtsezkoenak dira azpiprogrametan, }
{ larrietan dauden aginduen inguruan dabiltzate gainerako agindu guztiak. }
{ Konpiladorearen ingurune barrurik programa hau exekutatzean, MENUAK.DAT eta }
{ MAHAIAK.DAT datu-fitxategiak C:\Dev-Pas karpetan kokatu behar dira. }
program JatetxeaDerrigorrezkoAginduak_2024;
uses
crt, sysutils;
const
iMAHAIEN_MAX = 10;
iMENUEN_MAX = 7;
iAULKI_KOP_MAX = 4;
type
integer = smallint; { INTEGER datu-motek 2 byte hartzera behartzen da }
real = double; { REAL datu-motek 8 byte erabiltzera behartzen da }
tsKate99 = string[99];
tsKate20 = string[20];
trdMahaia = record
iMahaiZbk : integer;
iAulkiKop : integer;
boLibre : boolean;
sErreserbaIzena: tsKate20;
iMahaikideKop : integer;
end;
tfrdMahaiak = file of trdMahaia;
trdMenua = record
sIzena : tsKate20;
rPrezioa : real;
sAsteEguna: tsKate20;
end;
tfrdKarta = file of trdMenua;
tardKarta = array[1..iMENUEN_MAX] of trdMenua;
tarKontua = array[1..iMAHAIEN_MAX] of real;
tfrIrabaziak = file of real;
{----------------Programaren menua------------------}
function fncAukerenMenua: char;
var
cAukera: char;
begin
clrscr;
writeln('AUKEREN MENUA':33);
writeln('=============':33);
writeln('1. ':20, 'Erakutsi jatetxeko mahaien egoera');
writeln('2. ':20, 'Erreserbatu mahaia');
writeln('3. ':20, 'Menuak erakutsi');
writeln('4. ':20, 'Jatekoa eskatu');
writeln('5. ':20, 'Kontua eskatu eta ordaindu');
writeln('0. ':20, 'Programatik irten');
writeln('-----------------':37);
repeat
write('Zure aukera: ':33);
READLN(cAukera); (* KARAKTERE BAT TEKLATUZ IRAKURRI *)
until (cAukera >= '0') and (cAukera <= '5');
FNCAUKERENMENUA := cAukera; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{----------------Asteguna aukeratu------------------}
function fnsAstegunaZehaztu: tsKate20;
var
cAukera: char;
begin
clrscr;
writeln('ASTEGUNAK':29);
writeln('=========':29);
writeln('1. ':20, 'Astelehena');
writeln('2. ':20, 'Asteartea');
writeln('3. ':20, 'Asteazkena');
writeln('4. ':20, 'Osteguna');
writeln('5. ':20, 'Ostirala');
writeln('--------------':34);
repeat
write('Zure aukera: ':33);
READLN(cAukera); (* KARAKTERE BAT TEKLADUZ IRAKURRI *)
until (cAukera >= '1') and (cAukera <= '5');
case cAukera of
'1': FNSASTEGUNAZEHAZTU := 'Astelehena'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'2': FNSASTEGUNAZEHAZTU := 'Asteartea'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'3': FNSASTEGUNAZEHAZTU := 'Asteazkena'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'4': FNSASTEGUNAZEHAZTU := 'Osteguna'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'5': FNSASTEGUNAZEHAZTU := 'Ostirala'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
end;
{----------------Menuen fitxategiko datuak arrayan kargatu------------------}
procedure MenuenArrayaKargatuFitxategitik(sFitxIzenMenuak: tsKate99;
sAsteEgunBat: tsKate20;
var ardKarta: tardKarta;
var iLuzera: integer);
var
rdMenuBat: trdMenua;
frdKarta : tfrdKarta;
begin
assign(frdKarta, sFitxIzenMenuak);
reset(frdKarta);
iLuzera := 0;
while not eof(frdKarta) do
begin
READ(frdKarta, rdMenuBat); (* ERREGISTRO BAT FITXATEGITIK IRAKURRI *)
if upcase(rdMenuBat.sAsteEguna) = upcase(sAsteEgunBat) then
begin
iLuzera := iLuzera +1;
ARDKARTA[iLuzera] := rdMenuBat; (* ARRAYAREN ELEMENTU BAT ALDATU *)
end;
end;
close(frdKarta);
end;
{----------------Kontuen arrayak hasieran 0.0 euro posizio guztietan------------------}
procedure KontuenArrayaHasieratu(var arKontua: tarKontua);
var
k: integer;
begin
for k:=1 to iMAHAIEN_MAX do
ARKONTUA[k] := 0.0; (* ARRAYAREN ELEMENTU BAT ALDATU *)
end;
{----------------Mahaien egoera erakutsi------------------}
procedure MahaiakErakutsi(sFitxIzenMahaiak: tsKate99);
var
frdMahaiak: tfrdMahaiak;
rdMahaiBat: trdMahaia;
begin
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
writeln('------------------------------------------------------------------------');
writeln('MAHAIA':10, 'AULKIAK':10, 'MAHAIKIDEAK':15, 'ERABILGARRITASUNA':28);
writeln('------------------------------------------------------------------------');
while not eof(frdMahaiak) do
begin
read(frdMahaiak, rdMahaiBat);
WRITE(rdMahaiBat.iMahaiZbk:10); (* PANTAILAN IDATZI *)
WRITE(rdMahaiBat.iAulkiKop:10); (* PANTAILAN IDATZI *)
WRITE(rdMahaiBat.iMahaikideKop:15); (* PANTAILAN IDATZI *)
if rdMahaiBat.boLibre then
WRITE('Libre':16) (* PANTAILAN IDATZI *)
else
WRITE('Erreserbatua: ':25, rdMahaiBat.sErreserbaIzena); (* PANTAILAN IDATZI *)
writeln;
end;
writeln('------------------------------------------------------------------------');
close(frdMahaiak);
end;
{----------------Mahaia erreserbatu------------------}
procedure MahaiaErreserbatu(sFitxIzenMahaiak: tsKate99;
sBezeroIzena: tsKate20;
iMahaikideak: integer);
var
frdMahaiak : tfrdMahaiak;
rdMahaiBat : trdMahaia;
iAulkiKopurua : integer;
boMahaiaErreserbatua: boolean;
begin
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
boMahaiaErreserbatua := FALSE;
iAulkiKopurua := iMahaikideak;
// Kopuruarekin bat datorren mahai eskuragarria bilatu
repeat
writeln('sBezeroIzena = ', sBezeroIzena, 'iMahaikideak = ':20, iMahaikideak, 'iAulkiKopurua = ':20, iAulkiKopurua);
while not eof(frdMahaiak) and not boMahaiaErreserbatua do
begin
READ(frdMahaiak, rdMahaiBat); (* FITXATEGITIK IRAKURRI *)
if (rdMahaiBat.iAulkiKop = iAulkiKopurua) and rdMahaiBat.boLibre then
begin
rdMahaiBat.boLibre := FALSE;
rdMahaiBat.sErreserbaIzena := sBezeroIzena;
rdMahaiBat.iMahaikideKop := iMahaikideak;
SEEK(frdMahaiak, filepos(frdMahaiak) - 1); (* POSIZIO EGOKIAN KOKATU *)
WRITE(frdMahaiak, rdMahaiBat); (* FITXATEGIAN IDATZI *)
writeln('Erreserba gauzatu da, mahai zenbakia: ':40, rdMahaiBat.iMahaiZbk);
boMahaiaErreserbatua := TRUE;
end
end;
iAulkiKopurua := iAulkiKopurua + 1;
seek(frdMahaiak, 0);
until (iAulkiKopurua > iAULKI_KOP_MAX) or boMahaiaErreserbatua;
if not boMahaiaErreserbatua then
WRITELN('Eskatutako mahaikide kopururako tokirik ez dago.'); (* PANTAILAN IDATZI *)
close(frdMahaiak);
end;
{----------------Menua erakutsi------------------}
procedure EgunekoMenuakPantailaratu(const ardKarta: tardKarta; iLuzera: integer);
var
k: integer;
begin
writeln('--------------------------------------------------------------');
writeln('ZBK.':6, 'MENUA':14, 'PREZIOA':15, 'ASTEGUNA':15);
writeln('--------------------------------------------------------------');
for k:=1 to iLuzera do (* PANTAILAN IDATZI *)
WRITELN(k:5, ardKarta[k].sIzena:15, ardKarta[k].rPrezioa:10:2, ' Euro', ardKarta[k].sAsteEguna:15);
writeln('--------------------------------------------------------------');
end;
{----------------Mandatua------------------}
procedure Mandatua( sFitxIzenMahaiak: tsKate99;
iMahaia: integer;
const ardGaurkoKarta: tardKarta;
iZenbatMenuGaur: integer;
var arKontua: tarKontua);
var
iKont : integer;
frdMahaiak: tfrdMahaiak;
rdMahaiBat: trdMahaia;
iMenuZbk : integer;
begin
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
seek (frdMahaiak, iMahaia-1);
read(frdMahaiak, rdMahaiBat);
close(frdMahaiak);
if rdMahaiBat.iMahaikideKop = 0 then
writeln(iMahaia, '. zenbakidun mahaia libre dago')
else
begin
writeln('Eskatuko den menu kopurua: ',rdMahaiBat.iMahaikideKop);
arKontua[iMahaia] := 0.0; // soberan array hori hasieratuta dagoelako
for iKont:=1 to rdMahaiBat.iMahaikideKop do
begin
repeat
write('Aukeratu ', iKont, '. mahaikidearen menua: ');
READLN(iMenuZbk); (* MENUA AUKERATU *)
until (iMenuZbk >= 1) and (iMenuZbk <= iZenbatMenuGaur);
ARKONTUA[iMahaia] := arKontua[iMahaia] + ardGaurkoKarta[iMenuZbk].rPrezioa;
end; (* KONTUEN ARRAYA EGUNERATU *)
end;
end;
{----------------Ordaindu------------------}
function fnrOrdaindu(const arKontua: tarKontua;
iMahaia: integer): real;
begin
FNRORDAINDU := arKontua[iMahaia]; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{----------------Kontuen arrayaren edukia erakutsi------------------}
procedure KontuenArrayaErakutsi(const arKontua: tarKontua);
var
k: integer;
begin
for k:=1 to iMAHAIEN_MAX do
WRITELN(k:12, '. mahaia: ', ARKONTUA[k]:0:2, ' euro'); (* ARRAYAREN ELEMENTU BAT PANTAILARATU *)
end;
{----------------Ordaindu ondoren mahaia askatu------------------}
procedure MahaiaAskatu(sFitxIzenMahaiak: tsKate99;
iMahaiZenbakia: integer);
var
frdMahaiak: tfrdMahaiak;
rdMahaiBat: trdMahaia;
begin
writeln('Kontua ordaindu ondoren, mahaia libratzen...');
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
seek (frdMahaiak, iMahaiZenbakia -1);
read(frdMahaiak, rdMahaiBat);
write('Mahai zenbakia: ', rdMahaiBat.iMahaiZbk);
write('Aulkiak: ':14, rdMahaiBat.iAulkiKop);
write('Mahaikideak: ':18, rdMahaiBat.iMahaikideKop);
write('Bezeroa: ':14, rdMahaiBat.sErreserbaIzena);
writeln;
RDMAHAIBAT.iMahaikideKop := 0; (* MEMORIAN EGUNERATU *)
RDMAHAIBAT.boLibre := TRUE; (* MEMORIAN EGUNERATU *)
RDMAHAIBAT.sErreserbaIzena := ''; (* MEMORIAN EGUNERATU *)
write('Mahai zenbakia: ', rdMahaiBat.iMahaiZbk);
write('Aulkiak: ':14, rdMahaiBat.iAulkiKop);
write('Mahaikideak: ':18, rdMahaiBat.iMahaikideKop);
write('Bezeroa: ':14, rdMahaiBat.sErreserbaIzena);
seek (frdMahaiak, iMahaiZenbakia -1);
WRITE(frdMahaiak, rdMahaiBat); (* FITXATEGIAN EGUNERATU *)
close(frdMahaiak);
end;
{----------------Irabaziak arraytik fitxategira------------------}
procedure IrabaziakGorde(sFitxIzenIrabaziak: tsKate99; const arKontua: tarKontua);
var
frIrabaziak: tfrIrabaziak;
k : integer;
begin
assign(frIrabaziak, sFitxIzenIrabaziak);
rewrite(frIrabaziak);
for k:=1 to iMAHAIEN_MAX do (* MAHAI BAKOITZEKO, ERREPIKATU *)
WRITE(frIrabaziak, arKontua[k]); (* ERREAL BAT FITXATEGIAN GORDE *)
close(frIrabaziak);
end;
{----------------programa nagusia------------------}
var
sFitxIzenMahaiak : tsKate99;
sFitxIzenMenuak : tsKate99;
sFitxIzenIrabaziak: tsKate99;
sAsteEgunBat : tsKate20;
ardGaurkoKarta : tardKarta;
iZenbatMenuGaur : integer;
cAukera : char;
sBezeroIzena : tsKate20;
iMahaikideak : integer;
iMahaia : integer;
arKontua : tarKontua;
begin
clrscr;
writeln('Jatetxeko datuak gordetzen dituzten bi fitxategien izenak zehaztu...');
write('Mahaien fitxategiaren izena eman (adibidez, MAHAIAK.DAT): ');
readln(sFitxIzenMahaiak);
write('Menuen fitxategiaren izena sartu (esaterako, MENUAK.DAT): ');
readln(sFitxIzenMenuak);
if fileexists(sFitxIzenMahaiak) and fileexists(sFitxIzenMenuak) then
begin
write('Gaurko asteguna eman: ');
sAsteEgunBat := fnsAstegunaZehaztu;
MenuenArrayaKargatuFitxategitik(sFitxIzenMenuak, sAsteEgunBat, ardGaurkoKarta, iZenbatMenuGaur);
KontuenArrayaHasieratu(arKontua);
repeat
cAukera := fncAukerenMenua;
clrscr;
case cAukera of
'1': MahaiakErakutsi(sFitxIzenMahaiak);
'2': begin
write('Bezeroaren izena eman: ':40);
readln(sBezeroIzena);
write('Mahaikideen kopurua eman: ':40);
readln(iMahaikideak);
MahaiaErreserbatu(sFitxIzenMahaiak, sBezeroIzena, iMahaikideak);
end;
'3': EgunekoMenuakPantailaratu(ardGaurkoKarta, iZenbatMenuGaur);
'4': begin
repeat
write('Janaria eskatzen, mahaiaren zenbakia eman (1 eta ', iMAHAIEN_MAX, ' artekoa): ');
readln(iMahaia);
until (iMahaia >= 1) and (iMahaia <= iMAHAIEN_MAX);
EgunekoMenuakPantailaratu(ardGaurkoKarta, iZenbatMenuGaur);
Mandatua(sFitxIzenMahaiak, iMahaia, ardGaurkoKarta, iZenbatMenuGaur, arKontua);
writeln;
writeln('Mahai guztien kontuak gordetzen duen arrayaren edukia:');
KontuenArrayaErakutsi(arKontua);
end;
'5': begin
repeat
write('Kontua eskatu duen mahaiaren zenbakia eman (1 eta ', iMAHAIEN_MAX, ' artekoa): ');
readln(iMahaia);
until (iMahaia >= 1) and (iMahaia <= iMAHAIEN_MAX);
if fnrOrdaindu(arKontua, iMahaia) = 0.0 then
writeln(iMahaia, '. zenbakidun mahaia libre dago edo ez da jatekorik eskatu')
else
begin (* MAHAIAK ORDAINDU BEHARREKOA PANTAILARATU *)
WRITELN(iMahaia, ' zenbakiko mahaiak ', fnrOrdaindu(arKontua, iMahaia):0:2, ' Euroko kontua ordaindu behar du.');
MahaiaAskatu(sFitxIzenMahaiak, iMahaia); (* MAHAIA ASKATU *)
end;
end;
'0': begin
sFitxIzenIrabaziak := 'IRABAZIAK_' + sAsteEgunBat + '.DAT';
IrabaziakGorde(sFitxIzenIrabaziak, arKontua);
end;
end;
writeln;
readln;
until cAukera = '0';
end
else (* FITXATEGIREN BAT EZ DENEAN *)
begin
if not fileexists(sFitxIzenMahaiak) then
writeln('ERROREA!! "', sFitxIzenMahaiak, '" fitxategirik ez dago.');
if not fileexists(sFitxIzenMenuak) then
writeln('ERROREA!! "', sFitxIzenMenuak, '" fitxategirik ez dago.');
writeln;
writeln('(RETURN sakatu programatik irteteko)');
readln;
end;
end. (* programaren amaiera *)
Fitxategiaren egitura taula batena da eta bertan agertzen diren zutabeen esanahia jarraian azaltzen da.
Ikaslea identifikatzeko NAN delako lehen zutabea erabiltzen da, zutabe horren arabera ordenaturik dago taula. Laborategiko nota hurrengo lau zutabetan ematen da: 1. KONTROLA (maximoa 10 puntu), LABORATEGIA (maximoa 0,5 puntu), 2. KONTROLA (maximoa 10 puntu) eta LABORATEGIA (maximoa 1 puntu) izenburuko zutabeak. Mintegiko nota banaturik dago PROIEKTUA eta 3. KONTROLA zutabeen artean, bien artean maximoa 1,5 puntu dira eta horien batura MINTEGIA zutabean erakusten da. Taularen azken bi zutabeak batukariak dira (batean maximoa 3 puntu dira, eta bestean 10 puntu dira). Taula ikusi:
Adieraz dezagun orain, irakasgaiaren azken kalifikazioa osatzeko, 1,5+1,5 puntu horiek nola uztartzen diren azterketa idatzian lortutako puntuekin. Horretarako, gogora dezagun aspaldi bateko Irakasgaiaren ebaluazioa blog-artikulua:
Azterketa aurretik 3 puntu lor daitezke ikasturtearen zehar mintegian eta laborategian egindako lanari esker:
Laborategiko 1,5 puntu (1. eta 2. kontrolak)
Mintegiko 1,5 puntu (3. kontrola)
Azterketa idatziak 7 puntu emango dizkio azken notari. Azterketa idatziak bi zati izango ditu (galderak eta programa) banaketa honelakoxea delarik:
Azterketa idatziaren alde teorikoak %30eko pisua izango du, eta ondorioz 2,1 puntu emango dizkio irakasgaiaren azken notari
Azterketa idatziaren programak %70eko pisua izango du, eta ondorioz 4,9 puntu emango dizkio irakasgaiaren azken notari
Irakasgaia gainditu ahal izateko, derrigorrezkoa da azterketa idatziaren erdia egitea, hots, 7 puntuetatik 3,5 puntu lortzea
Deialdi berezian ez dira kontutan hartuko ikasturtearen zehar mintegian eta laborategian egindako lanak. Horregatik, deialdi berezian azterketa idatzian lorturiko emaitza irakasgaiaren kalifikazioa izango da
Dakigunez, beste urte batzuetako teoriako azterketen soluzio osoak ez ematea erabaki du irakasle taldeak. Enuntziatuarekin batera, lau aukeren artean zein den zuzena bai argiratuko da, baina ez da argitaratuko erantzun zuzen horren justifikazioa (ikusi hemen justifikazio adibide bat).
Teoriako galderak prestatze aldera, interesgarria izan dakikoke ikasleari galderaren kodea idaztea eta konpilatzea.
Hona hemen galdera baten enuntziatua. Aukera zuzenaren letra hautatzeaz gain, bere justifikazioa ondo azaltzea ikaslearen lana izango da azterketan:
Beste urte batzuetako teoriako azterketen soluzio osoak ez ematea erabaki du irakasle taldeak. Enuntziatuarekin batera, lau aukeren artean zein den zuzena bai argiratuko da, baina ez da argitaratuko erantzun zuzen horren justifikazioa.
Gauzak horrela, ikus eta ikas dezagun adibide bakar batekin teoriako galderei nola erantzun beharko litzatekeen. Hona hemen galdera baten enuntziatua, non informazioa hiru koloretan desberdindu den:
Beltzez Teoriako galderaren enuntziatuak, ikasleak azterketan jasoko duen informazio bakarra. eGelan argitaratu dira azken hiru kurtsoetako azterketen enuntziatuak
Moreaz Teoriako galderaren erantzun labur-laburra (lau aukeretatik egokiari dagokion letra). eGelan argitaratu dira azken hiru kurtsoetako azterketen erantzun laburrak
Urdinez Teoriako galderaren erantzunari dagokion justifikazioa. Ez dira argitaratuko
Galderaren erantzuna ontzat emateko justifikazio egokia derrigorrezkoa delako, hona hemen adibide bat ikasleak ikus dezan teoriako galderei nola erantzun beharko lukeen:
Ezaguna denez, Azterketa: 2023ko uztailaren deialdia izenburuko artikuluan azterkari buruzko informazio guzti-guztia dago, bai programari buruzkoa zein teoriari buruzkoa.
Berridatz dezagun uztaileko programa baina soilik derrigorrezko aginduak idatziz (letra larrietan idatzirik ematen diren aginduak). Ez dugu esan nahi gainerako aginduak soberan daudenik, baizik eta letra larrietan idatziko ditugunak berebiziko garrantzia dutela eta besteak horien menpekoak direla nolabait.
2023-06-30_Kromoak_DerrigorrezkoAginduak.pas
fitxategian jasota dagoen uztaileko programa berezian, letra larriz
nabarmendu dira ezinbestekoak diren aginduak. Konpiladorearen ingurune
barnetik programa hau exekutatzean, KROMOAK.DAT datu-fitxategia (edo JOKALARIAK.DAT datu-fitxategia) C:\Dev-Pas
karpetan kokatu behar da derrigorrez. Ikusi jarraian uztaileko programa bereziaren
kodea, non, aurreratu den bezala, azpiprograma
bakoitzean letra larrietan jarri diren aginduak garrantzitsutzat jo
daitezkeen:
{ Hitz larrietan idatzi diren aginduak funtsezkoenak dira azpiprogrametan, }
{ larraietan dauden aginduen inguruan dabiltzate gainerako agindu guztiak. }
{ Konpiladorearen ingurune barrurik programa hau exekutatzean, JOKALARIAK.DAT }
{ edo KROMOAK.DAT datu-fitxategiak C:\Dev-Pas karpetan kokatu behar dira. }
program KromoakDerrigorrezkoAginduak_2023ko_uztaila;
uses
crt, sysutils;
const
iMAX = 340;
type
integer = smallint; // INTEGER-entzat 2 byte erabiltzera behartzen da
tsKate25 = string[25];
tsKate199 = string[199];
trdBalioak = record
iDefentsan,
iKontrolean,
iErasoan,
iGuztira: integer;
end;
trdKromoa = record
iZenbakia : integer;
sIzena : tsKate25;
sTokia,
sTaldea : tsKate25;
rdBalioak : trdBalioak;
iZenbatAle: integer;
end;
tfrdBilduma = file of trdKromoa;
trdJokalaria = record
sIzena : tsKate25;
sTokia : tsKate25;
boHartuta: boolean;
end;
tardJokalariak = array[1..iMAX] of trdJokalaria;
tardNireTaldea = array[1..11] of trdJokalaria;
{------------------TALDEAREN KONFIGURAZIA------------------------------}
function fncKonfigurazioaHautatu: char;
var
cHautapena: char;
begin
writeln;
writeln('KONFIGURAZIOAK':20);
writeln('==============':20);
writeln(' A) 4-4-2 (atezain 1, 4 atzelari, 4 erdilari eta 2 aurrelari)':74);
writeln(' B) 4-5-1 (atezain 1, 4 atzelari, 5 erdilari eta aurrelari 1)':74);
writeln(' C) 4-3-3 (atezain 1, 4 atzelari, 3 erdilari eta 3 aurrelari)':74);
writeln(' D) 3-4-3 (atezain 1, 3 atzelari, 4 erdilari eta 3 aurrelari)':74);
writeln;
repeat
write('Zure aukera: ':20);
READLN(cHautapena); (* KASU EGOKIA AUKERATU *)
cHautapena := upcase(cHautapena);
until (cHautapena >= 'A') and (cHautapena <= 'D');
FNCKONFIGURAZIOAHAUTATU := cHautapena; (* BALIOA ITZULI *)
end;
{------------ARRAY BAT ELIKATU FITXATEGIKO DATUEKIN--------------------}
procedure FitxategikoDatuBatzukArrayBatera( sFitxIzen: tsKate199;
sPostuaZelaian: tsKate25;
var ardJokalariak: tardJokalariak;
var iLuzera: integer);
var
rdKromoBat: trdKromoa;
f_B : tfrdBilduma;
begin
assign(f_B, sFitxIzen);
reset(f_B);
iLuzera := 0;
while not eof(f_B) do
begin
READ(f_B, rdKromoBat); (* FITXATEGITIK IRAKURRI *)
IF (rdKromoBat.sTokia = sPostuaZelaian) AND (rdKromoBat.iZenbatAle > 0) THEN
BEGIN
iLuzera := iLuzera +1; (* ARRAYA ELIKATU *)
ardJokalariak[iLuzera].sIzena := rdKromoBat.sIzena;
ardJokalariak[iLuzera].sTokia := sPostuaZelaian;
ardJokalariak[iLuzera].boHartuta := FALSE;
END;
end;
close(f_B);
end;
{------------LORTUTAKO TALDEA PANTAILARATU----------------}
procedure TaldeaIkusi(const ardJokalariak: tardNireTaldea);
var
iKont: integer;
begin
writeln('IZENA':30, 'TOKIA ZELAIAN':20);
writeln('-----':30, '-------------':20);
FOR iKont:=1 TO 11 DO
BEGIN (* ARRAY OSOA PANTAILARATU *)
WRITELN(ardJokalariak[iKont].sIzena:30, ardJokalariak[iKont].sTokia:20);
END;
writeln;
end;
{-----------JOKALARI GEHIAGO NIRE TALDEAN------------------------------}
procedure JokalariakAukeratu( var ardJokalariak: tardJokalariak;
iLuzJokalariak: integer;
var ardNireTaldea: tardNireTaldea;
var iLuzNireTaldea: integer;
iZenbat: integer);
var
iKont: integer;
iZbk : integer;
begin
randomize;
FOR iKont:=1 TO iZenbat DO (* ERREPIKAPEN KOPURU JAKINA *)
BEGIN
repeat
iZbk := RANDOM(iLuzJokalariak) +1; (* AUZAZKO BALIO EGOKIA *)
write('iLuzJokalariak = ', iLuzJokalariak:3, 'iZbk = ':12, iZbk:3);
if ardJokalariak[iZbk].boHartuta then
writeln('JOKALARI HAU HARTUTA DAGO, ERREPIKATU!':42)
else
writeln;
until (not ardJokalariak[iZbk].boHartuta);
iLuzNireTaldea := iLuzNireTaldea +1;
ardNireTaldea[iLuzNireTaldea].sIzena := ardJokalariak[iZbk].sIzena;
ardNireTaldea[iLuzNireTaldea].sTokia := ardJokalariak[iZbk].sTokia;
ardNireTaldea[iLuzNireTaldea].boHartuta := TRUE;
ardJokalariak[iZbk].boHartuta := TRUE; (* ARRAYA ELIKATU *)
END;
end;
{--------JOKALARIA BILATU----------------------------------------------}
procedure JokalariaBilatu( sFitxIzen:tsKate199;
sJokalaria:tsKate25;
VAR RDKROMOBAT:trdKromoa); (* ERREGISTROA ITZULI *)
var
f_B : tfrdBilduma;
boAurkitua: boolean;
begin
assign(f_B, sFitxIzen);
reset(f_B);
boAurkitua := FALSE;
WHILE NOT boAurkitua AND NOT eof(f_B) DO
BEGIN
READ(f_B, rdKromoBat); (* FITXATEGITIK IRAKURRI *)
if upcase(rdKromoBat.sIzena) = upcase(sJokalaria) then
boAurkitua := TRUE
END;
{--------------------------------ariketa honetan ziurtatuta dago...
if not boAurkitua then
rdKromoBat.iZenbakia := -1;
--------------------------------...jokalaria aurkituko dela-------}
close(f_B);
end;
{------------------TAULA BEZALA ERAKUTSI-------------------------------}
procedure TaulaBezalaErakutsi(const rdKromoBat:trdKromoa);
begin
with rdKromoBat, rdBalioak do
begin
WRITE(iZenbakia:6); (* PANTAILAN IDATZI *)
WRITE(sIzena:17);
WRITE(sTokia:15);
WRITE(sTaldea:12);
WRITE(iDefentsan:6, iKontrolean:6, iErasoan:6, iGuztira:7);
writeln;
end;
end;
{-------------TALDEAREN PUNTUAK KALKULATU------------------------------}
function fniPuntuakKalkulatu( sFitxIzen: tsKate199;
const ardNireTaldea: tardNireTaldea): integer;
var
rdKromoBat: trdKromoa;
iKont : integer;
iMetatua : integer;
begin
IMETATUA := 0; (* HASIERAKETA *)
writeln('ZBK.':7, 'IZENA':16, 'TOKIA':15, 'TALDEA':12, 'DEF.':7,'KON.':6, 'ERA.':6, 'GUZT.':7);
writeln('--------------------------------------------------------------------------':76);
for iKont:=1 to 11 do
begin
JokalariaBilatu(sFitxIzen, ardNireTaldea[iKont].sIzena, rdKromoBat);
TaulaBezalaErakutsi(rdKromoBat);
IMETATUA := IMETATUA + rdKromoBat.rdBalioak.iGuztira; (* METAKETA *)
end;
writeln('--------------------------------------------------------------------------':76);
FNIPUNTUAKKALKULATU := IMETATUA; (* BALIOA ITZULI *)
end;
{======PROGRAMA NAGUSIAREN ALADAGIAK===================================}
var
sFitxIzen : tsKate199;
ardAtezainak : tardJokalariak;
ardAtzelariak : tardJokalariak;
ardErdilariak : tardJokalariak;
ardAurrelariak : tardJokalariak;
iLuzAtezainak : integer;
iLuzAtzelariak : integer;
iLuzErdilariak : integer;
iLuzAurrelariak : integer;
cAukera : char;
iNireAtzelariak : integer;
iNireErdilariak : integer;
iNireAurrelariak: integer;
ardNireTaldea : tardNireTaldea;
iLuzNireTaldea : integer;
iPuntuak : integer;
{=========PROGRAMA NAGUSIA=============================================}
begin
clrscr;
write('Fitxategiaren izena eman ("KROMOAK.DAT" edo "JOKALARIAK.DAT"): ');
readln(sFitxIzen);
if not fileexists(sFitxIzen) then
writeln('ERROREA!!! "', sFitxIzen, '" izeneko fitxategirik ez da')
else
begin
writeln;
writeln;
writeln('1. URRATSA: LAU ARRAYAK BETE');
writeln('============================');
writeln;
FitxategikoDatuBatzukArrayBatera(sFitxIzen, 'Atezaina', ardAtezainak, iLuzAtezainak);
FitxategikoDatuBatzukArrayBatera(sFitxIzen, 'Atzelaria', ardAtzelariak, iLuzAtzelariak);
FitxategikoDatuBatzukArrayBatera(sFitxIzen, 'Erdilaria', ardErdilariak, iLuzErdilariak);
FitxategikoDatuBatzukArrayBatera(sFitxIzen, 'Aurrelaria', ardAurrelariak, iLuzAurrelariak);
writeln;
writeln('2. URRATSA: TALDEAREN KONFIGURAZIOA ERABAKIZ TALDEA OSA DAITEKEEN FROGATU');
writeln('=========================================================================');
writeln;
writeln('Zure taldeak zer estrategia erabiliko du? Konfigurazioa bat hautatu');
cAukera := fncKonfigurazioaHautatu;
case cAukera of
'A': begin
iNireAtzelariak := 4;
iNireErdilariak := 4;
iNireAurrelariak := 2;
end;
'B': begin
iNireAtzelariak := 4;
iNireErdilariak := 5;
iNireAurrelariak := 1;
end;
'C': begin
iNireAtzelariak := 4;
iNireErdilariak := 3;
iNireAurrelariak := 3;
end;
'D': begin
iNireAtzelariak := 3;
iNireErdilariak := 4;
iNireAurrelariak := 3;
end;
end; { case }
if (iLuzAtezainak >= 1) and
(iLuzAtzelariak >= iNireAtzelariak) and
(iLuzErdilariak >= iNireErdilariak) and
(iLuzAurrelariak >= iNireAurrelariak) then
begin
writeln;
writeln;
writeln('3. URRATSA: TALDEA OSATU');
writeln('========================');
iLuzNireTaldea := 0;
writeln('------------------------------------------');
JokalariakAukeratu(ardAtezainak, iLuzAtezainak, ardNireTaldea, iLuzNireTaldea, 1);
writeln('------------------------------------------');
JokalariakAukeratu(ardAtzelariak, iLuzAtzelariak, ardNireTaldea, iLuzNireTaldea, iNireAtzelariak);
writeln('------------------------------------------');
JokalariakAukeratu(ardErdilariak, iLuzErdilariak, ardNireTaldea, iLuzNireTaldea, iNireErdilariak);
writeln('------------------------------------------');
JokalariakAukeratu(ardAurrelariak, iLuzAurrelariak, ardNireTaldea, iLuzNireTaldea, iNireAurrelariak);
writeln('------------------------------------------');
writeln;
writeln('Aukeratu den ', iNireAtzelariak, '-', iNireErdilariak, '-', iNireAurrelariak, ' konfigurazioa duen taldea hau da:');
writeln;
TaldeaIkusi(ardNireTaldea);
writeln;
writeln('4. URRATSA: TALDEAREN DATU GUZTIAK ERAKUTSI ETA BALIOA ZENBATU');
writeln('==============================================================');
writeln;
iPuntuak := fniPuntuakKalkulatu(sFitxIzen, ardNireTaldea);
writeln;
writeln('Nere taldearen balioa: ', iPuntuak, ' puntu');
writeln;
end { then, taldea osa daiteke }
else
writeln('Eskatu duzun ', iNireAtzelariak, '-', iNireErdilariak, '-', iNireAurrelariak, ' konfigurazioko talderik ezin daiteke osatu!!!');
end; { else, datu-fitxategirik ez da }
writeln;
writeln;
writeln;
writeln('-------------------------');
writeln('Programa bukatzera doa!!!');
writeln('-------------------------');
readln;
end. { PROGRAMAREN AMAIERA }
DatuFitxategiaSortu.pas bezero-programa (bilduma21 unitatearekin, bilduma30 unitatearekin edo bilduma39 unitatearekin batera karpeta berean kokatu, adibidez C:\GurePrograma karpetan)
bilduma21.pas unitatearen iturburu-kodea (DatuFitxategiaSortu.pas bezero-programarekin batera karpeta berean kokatu, adibidez C:\GurePrograma karpetan), edo...
bilduma30.pas unitatearen iturburu-kodea (DatuFitxategiaSortu.pas bezero-programarekin batera karpeta berean kokatu, adibidez C:\GurePrograma karpetan), edo...
bilduma39.pas unitatearen iturburu-kodea (DatuFitxategiaSortu.pas bezero-programarekin batera karpeta berean kokatu, adibidez C:\GurePrograma karpetan)
Datu-fitxategiak:
KROMOAK.DAT datu-fitxategiak 21, 30 edo 39 elementu izan ditzake (bilduma21.pas unitatearekin, bilduma30.pas unitatearekin edo bilduma39.pas unitatearekin sortu bada)
JOKALARIAK.DAT datu-fitxategiak 340 elementu ditu eta bezero-programarekin batera karpeta berean kokatu (adibidez, C:\GurePrograma karpetan)
2023-06-30_TaldeaKromoekin.pas programak neurri desberdineko datu-fitxategiak prozesa ditzake, adibidez 21, 30 edo 39 elementuko datu-fitxategiak (gehienez 340 elementu izan ditzake datu-fitxategiak). Hau da bilduma21 izeneko unitatearen interfazea (bilduma30 unitatearen eta bilduma39 unitatearen interfazeak berdinak dira, eta aldea BildumarenFitxategiaSortu prozeduran dago):
Ezaguna denez, Azterketa: 2023ko maiatzaren deialdia izenburuko artikuluan azterkari buruzko informazio guzti-guztia dago. Heltzear den uztaileko deialdiari dagokion programa prestatze aldera, berridatz dezagun maiatzeko programa baina soilik derrigorrezko aginduak idatziz (letra larrietan idatzirik ematen diren aginduak). Ez dugu esan nahi gainerako aginduak soberan daudenik, baizik eta letra larrietan idatziko ditugunak berebiziko garrantzia dutela eta besteak horien menpekoak direla nolabait.
2023-05-24_Kromoak_DerrigorrezkoAginduak.pas fitxategian jasota dagoen maiatzeko programa berezian, letra larriz nabarmendu dira ezinbestekoak diren aginduak. Konpiladorearen ingurune barnetik programa hau exekutatzean, JOKALARIAK.DAT datu-fitxategia C:\Dev-Pas karpetan kokatu behar da derrigorrez. Maiatzeko programa bereziaren kodea jarraian ikusi, non, aurreratu den bezala, azpiprograma bakoitzean letra larrietan jarri diren aginduak garrantzitsutzat jo daitezkeen:
{ Hitz larrietan idatzi diren aginduak funtsezkoenak dira azpiprogrametan, }
{ larraietan dauden aginduen inguruan dabiltzate gainerako agindu guztiak. }
{ Konpiladorearen ingurune barrurik programa hau exekutatzean, JOKALARIAK.DAT }
{ delako datu-fitxategiak C:\Dev-Pas karpetan kokatu behar da. }
{ Programa exekutazean JOKALARIAK.DAT delako datu-fitxategia erabili behar da }
{ derrigorrez, 340 kromo dituen bilduma batekin lan egitea espero delako. }
{ Bildumaren fitxategiak beti 340 kromo dituelako, programa honek darabilen }
{ arrayarekin lan egiteko luzera logikoa zehaztean aldagairik ez da behar. }
program KromoakDerrigorrezkoAginduak_2023;
uses
crt, sysutils;
const
iMAX = 340; // enuntziatuan 471
type
integer = smallint; (* INTEGER-entzat 2 byte erabiltzera behartzen da *)
tsKate25 = string[25];
tsKate199 = string[199];
trdBalioak = record
iDefentsan,
iKontrolean,
iErasoan,
iGuztira: integer;
end;
trdKromoa = record
iZenbakia : integer;
sIzena : tsKate25;
sTokia,
sTaldea : tsKate25;
rdBalioak : trdBalioak;
iZenbatAle: integer;
end;
tfrdBilduma = file of trdKromoa;
taiBilduma = array[1..iMAX] of integer;
{------------------menua---------------------}
function fncMenua: char;
var
cHautapena: char;
begin
clrscr;
writeln('AUKEREN MENUA':20);
writeln('=============':20);
writeln;
writeln(' 1 Kromo guztien informazioa erakutsi');
writeln(' 2 Falta diren kromoak zerrendatu');
writeln(' 3 Kromo bat sartu');
writeln(' 4 Kromo bat trukatu');
writeln(' 5 Jokalari baten informazioa erakutsi');
writeln(' 0 Programatik irten');
writeln;
repeat
write('Zure aukera: ':20);
READLN(cHautapena); (* KARAKTERE BAT TEKLADUZ IRAKURRI *)
until (cHautapena >= '0') and (cHautapena <= '5');
FNCMENUA := cHautapena; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{------------------arraya elikatu fitxategiko datuekin--------------}
procedure FitxategikoDatuakArrayra(sFitxIzen:tsKate199; var aiBilduma:taiBilduma);
var
rdKromoBat: trdKromoa;
f_B : tfrdBilduma;
begin
assign(f_B, sFitxIzen);
reset(f_B);
while not eof(f_B) do
begin
READ(f_B, rdKromoBat); (* ERREGISTRO BAT IRAKURRI *)
aiBilduma[rdKromoBat.iZenbakia] := rdKromoBat.iZenbatAle;
end;
close(f_B);
end;
{------------------taula bezala erakutsi---------------------}
procedure TaulaBezalaErakutsi(const rdKromoBat:trdKromoa);
begin
with rdKromoBat, rdBalioak do
begin
WRITE(iZenbakia:4); (* PANTAILAN IDATZI *)
WRITE(sIzena:16);
WRITE(sTokia:15);
WRITE(sTaldea:12);
WRITE(iDefentsan:6, iKontrolean:5, iErasoan:5, iGuztira:6);
WRITELN(iZenbatAle:6);
end;
end;
{------------------kromo bat erakutsi---------------------}
procedure KromoBatErakutsi(const rdKromoBat:trdKromoa);
begin
with rdKromoBat, rdBalioak do
begin
WRITELN('Kromo zenbakia: ':25, iZenbakia); (* PANTAILAN IDATZI *)
WRITELN('Izena: ':25, sIzena);
WRITELN('Tokia zelaian: ':25, sTokia);
WRITELN('Taldea: ':25, sTaldea);
WRITELN('Balioa Atzelarian: ':25, iDefentsan:3);
WRITELN('Jokuaren kontrolean: ':25, iKontrolean:3);
WRITELN('Balioa erasoan: ':25, iErasoan:3);
WRITELN('Balioa orotara: ':25, iGuztira:3);
WRITELN('Ale kopurua: ':25, iZenbatAle:3);
end;
end;
{------------------bilduma erakutsi------------------}
procedure BildumaErakutsi(sFitxIzen:tsKate199);
var
rdKromoBat: trdKromoa;
f_B : tfrdBilduma;
begin
assign(f_B, sFitxIzen);
reset(f_B);
writeln;
writeln('ZBK':4, 'IZENA':16, 'TOKIA':15, 'TALDEA':12, 'DEF':6,'KON':5, 'ERA':5, 'GUZT':6, 'KOP':6);
writeln(' --------------------------------------------------------------------------');
while not eof(f_B) do
begin
READ(f_B, rdKromoBat); (* ERREGISTRO BAT IRAKURRI *)
TAULABEZALAERAKUTSI(rdKromoBat); (* ERREGISTROA PANTAILARATU *)
end;
writeln(' --------------------------------------------------------------------------');
close(f_B);
end;
{------------------falta diren kromoen zenbakiak erakutsi------------}
procedure FaltaDirenakZerrendatu(const aiBilduma:taiBilduma);
var
iKont : integer;
iZenbatBai: integer;
begin
iZenbatBai := 0;
writeln;
writeln('FALTA DIREN KROMOEN ZERRENDA':54);
writeln('----------------------------':54);
FOR iKont:=1 TO iMAX DO (* ARRAY OSOA PROZESATU *)
BEGIN
if aiBilduma[iKont] = 0 then
WRITE(iKont:4) (* PANTAILAN IDATZI *)
else
begin
WRITE('---':4); (* PANTAILAN IDATZI *)
iZenbatBai := iZenbatBai + 1;
end;
if iKont mod 20 = 0 then
WRITELN; (* HURRENGO ERRENKADA *)
END;
writeln;
writeln;
writeln(iZenbatBai, ' kromo dituzu eta ', iMAX -iZenbatBai, ' kromo falta zaizkizu');
end;
{------------------kromo berri baten baten balioak eguneratu----------}
procedure KromoBerriarenBalioakEguneratu(sFitxIzen:tsKate199; iZbk:integer);
var
rdKromoBat: trdKromoa;
f_B : tfrdBilduma;
begin
assign(f_B, sFitxIzen);
reset(f_B);
SEEK(f_B, iZbk-1); (* POSIZIO EGOKIAN KOKATU *)
READ(f_B, rdKromoBat); (* FITXATEGITIK IRAKURRI *)
with rdKromoBat,rdBalioak do
begin
write('Balioa defensan: ':25);
readln(iDefentsan);
write('Jokuaren kontrolean: ':25);
readln(iKontrolean);
write('Balioa erasoan: ':25);
readln(iErasoan);
iGuztira := iDefentsan + iKontrolean + iErasoan;
writeln('Guztira: ':25, iGuztira);
end;
SEEK(f_B, iZbk-1); (* POSIZIO EGOKIAN KOKATU *)
WRITE(f_B, rdKromoBat); (* ETA FITXATEGIAN IDATZI *)
close(f_B);
end;
{------------------jokalaria bilatu-------------------------}
procedure JokalariaBilatu( sFitxIzen:tsKate199;
sJokalaria:tsKate25;
VAR RDKROMOBAT:trdKromoa); (* ERREGISTROA ITZULI *)
var
f_B : tfrdBilduma;
boAurkitua: boolean;
begin
assign(f_B, sFitxIzen);
reset(f_B);
boAurkitua := FALSE;
while not boAurkitua and not eof(f_B) do
begin
READ(f_B, rdKromoBat); (* FITXATEGITIK IRAKURRI *)
if upcase(rdKromoBat.sIzena) = upcase(sJokalaria) then
boAurkitua := TRUE
end;
if not boAurkitua then
rdKromoBat.iZenbakia := -1;
close(f_B);
end;
{------------------fitxaegiaren datuak arraytik eguneratu---------}
procedure EguneratuAleakFitxategianArraytik( sFitxIzen:tsKate199;
const aiBilduma:taiBilduma);
var
rdKromoBat: trdKromoa;
f_B : tfrdBilduma;
begin
assign(f_B, sFitxIzen);
reset(f_B);
while not eof(f_B) do
begin
READ(f_B, rdKromoBat); (* FITXATEGITIK IRAKURRI *)
if aiBilduma[rdKromoBat.iZenbakia] <> rdKromoBat.iZenbatAle then
begin
rdKromoBat.iZenbatAle := aiBilduma[rdKromoBat.iZenbakia];
SEEK(f_B, FilePos(f_B)-1); (* POSIZIO EGOKIAN KOKATU *)
WRITE(f_B, rdKromoBat); (* ETA FITXATEGIAN IDATZI *)
end;
end;
close(f_B);
end;
{==================programa nagusiaren aldagaiak==========}
var
sFitxIzen : tsKate199;
aiBilduma : taiBilduma;
cAukera,
cJarraitu : char;
iZbk,
iZbkJaso,
iZbkEman : integer;
sJokalaria: tsKate25;
rdKromoBat: trdKromoa;
{==================programa nagusia==================}
begin
clrscr;
write('Bildumaren fitxategiaren izena (JOKALARIAK.DAT): ');
readln(sFitxIzen);
if not fileexists(sFitxIzen) then
writeln('ERROREA!!! "', sFitxIzen, '" izeneko fitxaterik ez da')
else
begin
FitxategikoDatuakArrayra(sFitxIzen, aiBilduma);
repeat
cAukera := fncMenua;
case cAukera of
'1': BildumaErakutsi(sFitxIzen);
'2': FaltaDirenakZerrendatu(aiBilduma);
'3': begin
repeat
writeln;
write('Kromoaren zenbakia (1 eta ', iMAX, ' artekoa): ');
readln(iZbk);
until (iZbk >= 1) and (iZbk <= iMAX);
aiBilduma[iZbk] := aiBilduma[iZbk] +1;
if aiBilduma[iZbk] = 1 then
begin
writeln('Kromo berria delako datu hauek behar ditugu:');
KromoBerriarenBalioakEguneratu(sFitxIzen, iZbk);
end;
end;
'4': begin
writeln;
repeat
write('Hartzen duzun kromoaren zenbakia (1 eta ', iMAX, ' artekoa): ');
readln(iZbkJaso);
until (iZbkJaso >= 1) and (iZbkJaso <= iMAX);
repeat
write('Emaiten duzun kromoaren zenbakia (1 eta ', iMAX, ' artekoa): ');
readln(iZbkEman);
until (iZbkEman >= 1) and (iZbkEman <= iMAX);
case aiBilduma[iZbkEman] of
0: writeln('ERROREA!!! Kromo hori ez daukazu');
1: begin
write('Kromo horren ale bakarra daukazu. Trukatu nahi duzu? (B/E) ');
readln(cJarraitu);
if upcase(cJarraitu)='B' then
begin
aiBilduma[iZbkEman] := 0; (* kromo hori gabe geratu gara *)
aiBilduma[iZbkJaso] := aiBilduma[iZbkJaso] +1;
if aiBilduma[iZbkJaso] = 1 then
KromoBerriarenBalioakEguneratu(sFitxIzen, iZbkJaso);
end;
end;
else { case }
begin
aiBilduma[iZbkEman] := aiBilduma[iZbkEman] -1;
aiBilduma[iZbkJaso] := aiBilduma[iZbkJaso] +1;
if aiBilduma[iZbkJaso] = 1 then
KromoBerriarenBalioakEguneratu(sFitxIzen, iZbkJaso);
end;
end;
end;
'5': begin
writeln;
write('Pantailaratuko den jokalariaren izena: ');
readln(sJokalaria);
JokalariaBilatu(sFitxIzen, sJokalaria, rdKromoBat);
if rdKromoBat.iZenbakia <> -1 then
KromoBatErakutsi(rdKromoBat)
else
writeln('ERROREA!! "', sJokalaria, '" ez da aurkitu');
end;
'0': EguneratuAleakFitxategianArraytik(sFitxIzen, aiBilduma);
end; { case }
writeln;
writeln;
writeln ('RETURN sakatu jarritzeko');
write ('======================== ');
readln;
until cAukera = '0';
clrscr;
writeln('Programa bukatzean bildumaren egoera hauxe da:');
BildumaErakutsi(sFitxIzen);
readln;
end; { else }
end. { programaren amaiera }
