Klasera ez etortzea dela eta, 2023-24 ikasturtean teoriako klaseen parte-hartzea erregistratu zen eta ondoko irudian ikus daitekeen bezala, astelehenetan gelara datozen ikasleen ehunekoa %65,3ekoa izan da eta ostiraletan %42,9koa. Zenbaki onak izan gabe, ez dirudite txarrak direnik, baina hori horrela da mediak direlako. Izan ere, alde nabaria dago kurtsoaren hasierako eta bukaerako etorreren artean (kurtso hasieran ikasle gehien-gehienak klaseetara etorri ziren eta kurtso bukaerarako hutsegiteak ugariak izan ziren). Esan gabe doa, ostiraletako hutsegiteak askoz gehiago direla astelehenetako hutsegiteak baino:
2023-24 ikasturteko ikasleen parte-hartzea eskola magistraletan asterik aste
Azterketetara aurkeztu ez diren ikasleen kopuruak
Aurreko grafikoaren 15. asteko datuei erreparatuta, 37 ikasle bertaratu ziren azken astelehenean eta 30 ikasle bertaratu ziren azken ostiralean. Horregatik, media bezala, 34 ikasle bertaratu ziren azken astean eta ondorioz esan daiteke 74-34=40 ikaslek bazterturik (edo erdi bazterturik) zeukaten irakasgaia kurtsoa bukatzean.
Bestalde, azterketa desberdinetara zenbat ikasle aurkeztu zirenen kopuruak jaso ziren eta ondoko taulan bildu dira:
2023-24 ikasturteko azterketetara ez aurkeztuak 31. taldean
Goiko taulan adierazten den bezala, 1. kontroleko azterketara ikasle gehienak aurkeztu ziren, baina, hortik aurrera, hurrengo azterketara askoz ikasle gutxiagok parte hartu zuten.
5. astetik 11. astera bitartean gai garrantzitsu bat ematen da: azpiprogramak (7. astea). Dirudienez, azpiprogramak ulertzea eta erabiltzea zaila egiten zaio ikasle askori eta, ziur gaude, irakasgaiaren punturik kritikoena dela.
Ezaguna denez, Azterketa: 2024ko uztailaren deialdia izenburuko artikuluan azterkari buruzko informazio guzti-guztia dago, bai programari buruzkoa zein teoriari buruzkoa.
Berridatz dezagun uztaileko programa baina soilik derrigorrezko aginduak idatziz (letra larrietan idatzirik ematen diren aginduak).
Ez dugu esan nahi gainerako aginduak soberan daudenik, baizik eta letra larrietan idatziko ditugunak berebiziko garrantzia dutela eta besteak horien menpekoak direla nolabait.
Uztaileko programa osoa 2024-06-28_AparkalekuakFuntzionala.zip fitxategian bilduta dago; hau da, 2024-06-28_Aparkalekuak.pas bezero-programa eta honek behar dituen lau unitateak:
konst.pas
motak.pas
apark.pas
gaur.pas
Jarraian erakusten den 2024-06-28_Aparkalekuak_DerrigorrezkoAginduak.pas programa ez da guztiz funtzionala, bere azpiprograma batzuek itzultzen dituzten balioak beti berdinak direlako. Izan ere, azterketaren enuntziatuan adierazten da azpiprograma horiek ez direla garatu behar.
2024-06-28_Aparkalekuak_DerrigorrezkoAginduak.pas fitxategian jasota dagoen uztaileko programa berezian, letra larriz
nabarmendu dira ezinbestekoak diren aginduak. Programa hau exekutatzean, datu-fitxategiak C:\Datuak karpetan sortuko dira. Ikusi jarraian uztaileko programa bereziaren
kodea, non, aurreratu den bezala, azpiprograma bakoitzean letra larrietan jarri diren aginduak garrantzitsutzat jo
daitezkeen.
{ Hitz larrietan idatzi diren aginduak funtsezkoenak dira azpiprogrametan, }
{ larraietan dauden aginduen inguruan dabiltzate gainerako agindu guztiak. }
{ }
{ Datu-fitxategiak 'C:\Datuak\' direktorioan kokatuko dira. }
{ Programa hau ezin da egoki exekutatu, hiru prozeduren kodea falta delako. }
{ Programa funtzionala ikusteko, bilatu blogean "Aparkalekuak_2024" programa. }
program AparkalekuakDerrigorrezkoAginduak_2024;
uses
crt, sysutils;
const
ZENBAT_APARKALEKU = 100; { Parking-ak 100 aparkaleku-plaza ditu }
GAU_BATEN_KOSTUA = 15; { Gau bat igarotzearen kostua }
MINUTU_BATEN_KOSTUA = 0.011; { Minutu bakoitzeko kostua }
GAU_KOPURU_MAXIMOA = 2; { Zenbat gau onartzen dira }
MAX = 4080; { Array laguntzailearen neurria }
sBIDEA = 'C:\Datuak\'; { Datu-fitxategiak kokatzeko direktorioa }
type
integer = smallint; { INTEGER datu-motek 2 byte hartzera behartzen da }
real = double; { REAL datu-motek 8 byte erabiltzera behartzen da }
tsKate200 = string[200]; { Fitxategien izenak gordetzeko aldagaien datu-mota }
tsKate10 = string[10]; { Data batek UUUU-HH-EE formatuan 10 karaktere behar ditu }
tsKate8 = string[8]; { Une batek OO:MM:SS formatuan 8 karaktere behar ditu }
tsKate2 = string[2]; { Data edo une batetik bi digitu hartzeko kateentzako }
trdData = record
iUrtea, iHila, iEguna: integer;
end;
trdUnea = record
iOrduak, iMinutuak, iSegundoak: integer;
end;
trdAutoarenDatuak = record
sMatrikula : tsKate8;
rdSarreraData: trdData;
rdSarreraUnea: trdUnea;
rdIrteeraData: trdData;
rdIrteeraUnea: trdUnea;
iGauKopurua : integer;
rZenbatekoa : real;
end;
tardParking = array[1..MAX] of trdAutoarenDatuak;
tfrdParking = file of trdAutoarenDatuak;
{ Fitxategi baten existentzia aztertzen du. Ezezkoan, sortu egiten du }
procedure prFitxategiaSortu(sFitxIzen: tsKate200);
var
f: tfrdParking;
begin
assign(f, sFitxIzen);
REWRITE(f);
close(f);
writeln('"', sFitxIzen, '" izeneko fitxategia berriki sortu da');
end;
{ Aparkalekuaren fitxategiak dituen datuak array batera eraman.
Bide batez , irten ez diren autoen gau kopurua inkrementatu. }
procedure prFitxategitikArrayra( sFitxIzen : tsKate200;
var ardParking: tardParking;
var iLuzera : integer);
var
f: tfrdParking;
begin
{ Hasieran array hori hutsik dago }
iLuzera := 0;
{ Fitxategia zabaldu }
assign(f, sFitxIzen);
reset(f);
{ Fitxategia hasierak bukaeraino zeharkatu }
while not eof(f) do
begin
iLuzera := iLuzera + 1;
READ(f, ardParking[iLuzera]);
ARDPARKING[iLuzera].iGauKopurua := ardParking[iLuzera].iGauKopurua + 1;
end;
close(f);
end;
{ 100 aparkaleku izan arren, gehienez 4080 auto egon daitezke erregistraturik
arrayan, batzuk sartu eta irten egin direlako. Funtzio honek zenbatuko ditu
barruan daudela irten ez diren autoak. }
function fniZenbatAutoBarruan(const ardAparkalekua: tardParking;
iLuzera : integer): integer;
var
iKont, iZenbat: integer;
begin
iZenbat := 0;
for iKont:=1 to iLuzera do
begin
if ardAparkalekua[iKont].rZenbatekoa = 0.0 then
iZenbat := iZenbat +1;
end;
fniZenbatAutoBarruan := iZenbat;
end;
{ Menua }
function fncAukeraIrakurri: char;
var
cAukera: char;
begin
clrscr;
writeln;
writeln;
writeln('**************************** MENUA ****************************');
writeln(' 1. Auto baten sarrera');
writeln(' 2. Auto baten irteera');
writeln(' 3. Parking-ean dauden autoen informazioa pantailaratu');
writeln;
writeln(' 0. Amaitu');
writeln('***************************************************************');
writeln;
write(' Zure aukera hautatu: ');
repeat
READLN(cAukera); (* KARAKTERE BAT TEKLADUZ IRAKURRI *)
until (cAukera >= '0') and (cAukera <= '3');
FNCAUKERAIRAKURRI := cAukera; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{ Auto berri baten datuak irakurri eta dagokion erregistroa bete }
procedure SartutakoAutoarenDatuakLortu(var rdAutoa: trdAutoarenDatuak);
begin
writeln('Sartu berria den autoaren sarrerako datuak eskuratu dira:');
writeln('matrikula, sarrera-data eta sarrera-unea (gainerakoak 0 dira)');
with rdAutoa do
begin
sMatrikula := '1234-XYZ'; // beti berdina
rdSarreraData.iUrtea := 2024; // beti berdina
rdSarreraData.iHila := 6; // beti berdina
rdSarreraData.iEguna := 28; // beti berdina
rdSarreraUnea.iOrduak := 9; // beti berdina
rdSarreraUnea.iMinutuak := 20; // beti berdina
rdSarreraUnea.iSegundoak := 2; // beti berdina
rdIrteeraData.iUrtea := 0;
rdIrteeraData.iHila := 0;
rdIrteeraData.iEguna := 0;
rdIrteeraUnea.iOrduak := 0;
rdIrteeraUnea.iMinutuak := 0;
rdIrteeraUnea.iSegundoak := 0;
iGauKopurua := 0;
rZenbatekoa := 0.0;
writeln('"', sMatrikula,'"', ' autoaren sarrerako data: ', rdSarreraData.iUrtea, '-',
rdSarreraData.iHila, '-',
rdSarreraData.iEguna);
writeln('"', sMatrikula,'"', ' autoaren sarrerako unea: ', rdSarreraUnea.iOrduak, ':',
rdSarreraUnea.iMinutuak, ':',
rdSarreraUnea.iSegundoak);
end;
end;
{ Irteerako data baten datuak itzultzen duen prozedura }
procedure DataIrakurri(var rdIrteerarenData: trdData);
begin
rdIrteerarenData.iUrtea := 2024; // beti berdina
rdIrteerarenData.iHila := 6; // beti berdina
rdIrteerarenData.iEguna := 28; // beti berdina
end;
{ Irteerako une baten datuak itzultzen duen prozedura }
procedure UneaIrakurri(var rdIrteerarenUnea: trdUnea);
begin
rdIrteerarenUnea.iOrduak := 10; // beti berdina
rdIrteerarenUnea.iMinutuak := 50; // beti berdina
rdIrteerarenUnea.iSegundoak := 7; // beti berdina
{ Sarrerarekiko 90 minutu eta 5 segundoko egonaldia }
{ beti-beti ateratzen den kostua 90x0.11= 0.99 euro }
end;
{ Auto baten matrikula datua izanik, autoaren posizioa array barruan zehazten du
baldin eta oraindik irten ez bada (horretarako rZenbatekoa balioa erabiltzen da).
Matrikula ez badu aurkitzen edo aurkitzen badu autoa irten bada, -1 itzuli.
Bestela autoaren posizioa array barruan itzuli. }
function fniMatrikulaBilatu( sZeinMatrikula: tsKate8;
const ardParking : tardParking;
iLuzera : integer): integer;
var
boAurkitua: Boolean;
i: integer;
begin
boAurkitua := FALSE;
i := 1;
while (not boAurkitua) and (i <= iLuzera) do
{ Matrikula bilatu (eta rZenbatekoa 0 delarik) }
if (ardParking[i].sMatrikula = sZeinMatrikula) and
(ardParking[i].rZenbatekoa = 0.0)
then
boAurkitua := TRUE
else
i := i + 1;
if boAurkitua then
FNIMATRIKULABILATU := i (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
else
FNIMATRIKULABILATU := -1; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{ Segundoen kopurua kalkuatu }
function fnliSegundoakKalkulatu(const rdUnea: trdUnea): longint;
begin
FNLISEGUNDOAKKALKULATU := rdUnea.iOrduak*3600 + rdUnea.iMinutuak*60 + rdUnea.iSegundoak;
end;
{ Data erregistro bat kate bihurtzen du UU-HH-EE formatua duena }
{ Hemen garatu den arren, azterketan goiburua baino ez zen eskatu }
function fnsDataBihurtu(const rdData: trdData): tsKate10;
var
sKatea : tsKate10;
sBiDigitu: tsKate2;
begin
str(rdData.iUrtea, sKatea);
if length(sKatea) = 1 then
sKatea := '000' + sKatea;
sKatea := sKatea + '-';
str(rdData.iHila, sBiDigitu);
if length(sBiDigitu) = 1 then
sBiDigitu := '0' + sBiDigitu;
sKatea := sKatea + sBiDigitu + '-';
str(rdData.iEguna, sBiDigitu);
if length(sBiDigitu) = 1 then
sBiDigitu := '0' + sBiDigitu;
sKatea := sKatea + sBiDigitu;
FNSDATABIHURTU := sKatea; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{ Unea erregistro bat kate bihurtzen du OO:MM:SS formatua duena }
{ Hemen garatu den arren, azterketan goiburua baino ez zen eskatu }
function fnsUneaBihurtu(const rdUnea: trdUnea): tsKate8;
var
sKatea : tsKate8;
sBiDigitu: tsKate2;
begin
str(rdUnea.iOrduak, sKatea);
if length(sKatea) = 1 then
sKatea := '0' + sKatea;
sKatea := sKatea + ':';
str(rdUnea.iMinutuak, sBiDigitu);
if length(sBiDigitu) = 1 then
sBiDigitu := '0' + sBiDigitu;
sKatea := sKatea + sBiDigitu + ':';
str(rdUnea.iSegundoak, sBiDigitu);
if length(sBiDigitu) = 1 then
sBiDigitu := '0' + sBiDigitu;
sKatea := sKatea + sBiDigitu;
FNSUNEABIHURTU := sKatea; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{ Honako informazio hau pantailaratu: matrikula,
sarreraren data eta ordua, eta, gau kopurua }
procedure prAutoBatenDatuakPantailaratu(const rdAutoa: trdAutoarenDatuak);
var
sData: tsKate10;
sUnea: tsKate8;
begin
with rdAutoa do
begin
sData := fnsDataBihurtu(rdSarreraData);
sUnea := fnsUneaBihurtu(rdSarreraUnea);
WRITELN(sMatrikula:9, ' ':3, sData, ' ', sUnea, iGauKopurua:9); (* PANTAILARATU *)
end;
end;
procedure prGoikoLerroaErakutsi;
var
i: integer;
begin
writeln('MATRIKULA', 'SARRERA':22, 'GAUAK':9);
for i:=1 to 40 do
WRITE('-'); (* PANTAILARATU *)
WRITELN; (* ERRENKADA ALDATZEKO *)
end;
{ Une jakin batean aparkalekuan dauden autoen informazioa pantailaratu }
procedure prBarruanDaudenAutoakErakutsi(const ardAparkalekua: tardParking;
iLuzera : integer);
var
i: integer;
begin
writeln;
prGoikoLerroaErakutsi;
FOR i := 1 TO iLuzera DO (* ARRAY OSOA ARAKATU *)
if ardAparkalekua[i].rZenbatekoa = 0.0 then { autoa barruan da }
prAutoBatenDatuakPantailaratu(ardAparkalekua[i]);
end;
{ Auto baten egonaldiaren kostua kalkulatu }
procedure prZenbatekoaKalkulatu(var rdAutoa: trdAutoarenDatuak);
var
rEuroak : real;
iMinutuKopurua: longint;
begin
if rdAutoa.iGauKopurua > 0 then
{ Gau bat igaro ezkero, rZenbatekoa = iGauKopurua x 15 }
rEuroak := rdAutoa.iGauKopurua*GAU_BATEN_KOSTUA
else
begin
iMinutuKopurua := fnliSegundoakKalkulatu(rdAutoa.rdIrteeraUnea) -
fnliSegundoakKalkulatu(rdAutoa.rdSarreraUnea);
iMinutuKopurua := iMinutuKopurua div 60;
rEuroak := iMinutuKopurua*MINUTU_BATEN_KOSTUA;
end;
RDAUTOA.RZENBATEKOA := rEuroak; (* EMAITZA IRTEERAKO PARAMETROARI ESLEITU *)
end;
{ Array laguntzailearen datuak fitxategi desberdinetara eraman }
procedure prDatuakFitxategietanGorde(const ardParking : tardParking;
iLuzera : integer;
sFitxIzenHistorikoa,
sFitxIzenBezpera,
sFitxIzenGarabia : tsKate200);
var
i : integer;
fH, fB, fG: tfrdParking;
begin
{ Datu berriak gehitzeko aparkalekuaren fitxategi historikoa zabaldu }
assign(fH, sFitxIzenHistorikoa);
RESET(fH); (* AURREKOA MANTENDUZ INFORMAZIO BERRIA GEHITU *)
SEEK(fH, fileSize(fH)); (* FITXATEGIAREN BUKAERAN KOKATU ELEMENTUAK GEHITZEKO *)
{ Garabiaren eta bezperako fitxategiak sortu }
assign(fB, sFitxIzenBezpera);
REWRITE(fB); (* AURREKOA GALDUZ INFORMAZIO BERRIA GEHITU *)
assign(fG, sFitxIzenGarabia);
REWRITE(fG); (* AURREKOA GALDUZ INFORMAZIO BERRIA GEHITU *)
for i:=1 to iLuzera do
begin
with ardParking[i] do
{ Autoa irten da }
if rZenbatekoa <> 0.0 then
WRITE(fH, ardParking[i]) { FITXATEGI HISTORIKOAN IDATZI }
else { Autoa ez da irten }
if iGauKopurua = GAU_KOPURU_MAXIMOA then
WRITE(fG, ardParking[i]) { GARABIAREN FITXATEGIAN IDATZI }
else
WRITE(fB, ardParking[i]); { BEZPERAKO FITXATEGIAN IDATZI }
end;
{ Fitxategiak itxi }
close(fH);
close(fB);
close(fG);
end;
var {-------------------- Programa nagusiko aldagaiak ------------------}
sFitxIzenHistorikoa, sFitxIzenBezpera, sFitxIzenGarabia: tsKate200;
cAukera, cItxaron : char;
ardParking : tardParking;
iPlazaLibreak, iLuzeraArray, iPosizioa : integer;
rdIrteerarenUnea : trdUnea;
rdGaurkoData : trdData;
sGaurkoData : tsKate10;
sMatrikula : tsKate8;
rdAutoa : trdAutoarenDatuak;
begin {-------------------------- Programa Nagusia ----------------------}
writeln;
writeln('Aparkaleku bat kudeatzeko programa');
writeln('----------------------------------');
writeln('Informazioa gordeko duten fitxategien direktorioa: "', sBIDEA, '"');
writeln('Informazioa gordeko duten fitxategien izenak eman...');
writeln;
write('Parking-aren informazio historikoa (adib. HISTORIKOA): ');
readln(sFitxIzenHistorikoa);
sFitxIzenHistorikoa := sBIDEA + sFitxIzenHistorikoa + '.DAT';
{ Aparkalekuaren fitxategia existitzen da, bestela sortu }
if not fileExists(sFitxIzenHistorikoa) then
begin
{ Fitxategi historikoa hutsik sortu }
prFitxategiaSortu(sFitxIzenHistorikoa);
end;
write(' Bezperako jardueraren informazioa (adib. BEZPERAKOA): ');
readln(sFitxIzenBezpera);
sFitxIzenBezpera := sBIDEA + sFitxIzenBezpera + '.DAT';
{ Bezperako fitxategia existitzen da, bestela sortu }
if not fileExists(sFitxIzenBezpera) then
begin
{ Bezperako fitxategia hutsik sortu }
prFitxategiaSortu(sFitxIzenBezpera);
end;
write(' Garabiaren fitxategiaren izena (adib. GARABIA): ');
readln(sFitxIzenGarabia);
sFitxIzenGarabia := sBIDEA + sFitxIzenGarabia + '.DAT';
{ Array laguntzailea datuz bete }
prFitxategitikArrayra(sFitxIzenBezpera, ardParking, iLuzeraArray);
iPlazaLibreak := ZENBAT_APARKALEKU - fniZenbatAutoBarruan(ardParking, iLuzeraArray);
writeln;
writeln('Egunaren hasieran ', iPlazaLibreak, ' plaza-libre eskaintzen dira');
writeln;
writeln('Edozein tekla sakatu aurrera egiteko...');
cItxaron := readKey;
write(cItxaron);
repeat
cAukera := fncAukeraIrakurri;
writeln;
case cAukera of
'1': { Sarrera berria }
if iPlazaLibreak = 0 then { Tokirik ez dagoenean }
writeln('Aparkalekua beterik dago!')
else
begin
{ Tokia dago. Matrikula eta sarrerako ordua lortu }
SartutakoAutoarenDatuakLortu(rdAutoa);
iLuzeraArray := iLuzeraArray + 1;
ardParking[iLuzeraArray] := rdAutoa;
{ Aparkaleku-plaza bat gutxiago }
iPlazaLibreak := iPlazaLibreak - 1;
writeln;
writeln(iPlazaLibreak, ' aparkaleku-plaza libre geratzen dira oraindik');
end;
'2': begin { Irteera berria }
{ Matrikula eta irteerako ordua eskatu }
write('Irtetera doan autoaren matrikula eman (1234-XYZ): ');
readln(sMatrikula);
sMatrikula := upcase(sMatrikula);
{ Auto hori aparkaleku barruan dagoela frogatu }
iPosizioa := fniMatrikulaBilatu(sMatrikula, ardParking, iLuzeraArray);
if iPosizioa = -1 then
begin
{ Ez badago edo lehenago irten bada, errore mezua }
writeln(sMatrikula, ' matrikuladun auto hori ez dago aparkalekuan');
end
else
begin
writeln;
DataIrakurri(rdGaurkoData);
writeln('Autoaren irteerako data: ', rdGaurkoData.iUrtea, '-',
rdGaurkoData.iHila, '-',
rdGaurkoData.iEguna);
UneaIrakurri(rdIrteerarenUnea);
writeln('Autoaren irteerako unea: ', rdIrteerarenUnea.iOrduak, ':',
rdIrteerarenUnea.iMinutuak, ':',
rdIrteerarenUnea.iSegundoak);
{ Array elementuaren informazioa eguneratu: irteerako
eguna, irteerako ordua eta ordaindu beharreko zenbatekoa }
ardParking[iPosizioa].rdIrteeraData := rdGaurkoData;
ardParking[iPosizioa].rdIrteeraUnea := rdIrteerarenUnea;
prZenbatekoaKalkulatu(ardParking[iPosizioa]);
{ Ordaindu beharreko zenbatekoa erakutsi }
writeln('Egonaldiaren zenbatekoa ', ardParking[iPosizioa].rZenbatekoa:0:2, ' euro dira');
{ Plaza-libre kopurua eguneratu }
iPlazaLibreak := iPlazaLibreak + 1;
writeln;
writeln('Orain ', iPlazaLibreak, ' plaza-libre geratzen dira');
end;
end;
'3': { Aparkalekuan dauden autoen informazioa pantailaratu }
if iPlazaLibreak = ZENBAT_APARKALEKU then
writeln('Autorik ez, aparkalekua hutsik dago!')
else
prBarruanDaudenAutoakErakutsi(ardParking, iLuzeraArray);
'0': { Datuak dagozkien fitxategietan gorde }
prDatuakFitxategietanGorde(ardParking, iLuzeraArray,
sFitxIzenHistorikoa,
sFitxIzenBezpera,
sFitxIzenGarabia);
end; { case }
if cAukera <> '0' then
begin
writeln;
writeln('Edozein tekla sakatu aurrera egiteko...');
cItxaron := readKey;
write(cItxaron);
end;
until cAukera = '0';
DataIrakurri(rdGaurkoData);
sGaurkoData := fnsDataBihurtu(rdGaurkoData);
writeln('Gaurko (', sGaurkoData, ') lana bukatu denez, programa amaituko da.');
writeln;
writeln('=======================');
writeln('RETURN sakatu amaitzeko');
write ('=======================');
readln;
end. { PROGRAMAREN BUKAERA }
Datu-fitxategiak C:\Datuak karpetan kokatu behar dira. Haien izenak hauek izan daitezke:
HISTORIKOA.DAT datu-fitxategia
BEZPERAKOA.DAT datu-fitxategia
GARABIA.DAT datu-fitxategia
2024-06-28_Aparkalekuak.pas bezero-programak lau unitate behar ditu. Hona hemen, lau unitateen interfaze atalak:
Konstanteak:
unit konst;
INTERFACE
const
ZENBAT_APARKALEKU = 100; { Parking-ak 100 aparkaleku-plaza ditu }
GAU_BATEN_KOSTUA = 15; { Gau bat igarotzearen kostua }
MINUTU_BATEN_KOSTUA = 0.011; { Minutu bakoitzeko kostua }
GAU_KOPURU_MAXIMOA = 2; { Zenbat gau onartzen dira }
MAX = 4080; { Array laguntzailearen neurria }
sBIDEA = 'C:\Datuak\'; { Datu-fitxategiak kokatzeko direktorioa }
(* ---------------------------- interfazearen amaiera -------------------------- *)
Datu-motak:
unit motak;
INTERFACE
uses
konst, crt, sysutils;
type
integer = smallint; { INTEGER datu-motek 2 byte hartzera behartzen da }
real = double; { REAL datu-motek 8 byte erabiltzera behartzen da }
tsKate8 = string[8];
tsKate200 = string[200];
tsKate10 = string[10];
tsKate2 = string[2];
trdData = record
iUrtea, iHila, iEguna: integer;
end;
trdUnea = record
iOrduak, iMinutuak, iSegundoak: integer;
end;
trdAutoarenDatuak = record
sMatrikula : tsKate8;
rdSarreraData: trdData;
rdSarreraUnea: trdUnea;
rdIrteeraData: trdData;
rdIrteeraUnea: trdUnea;
iGauKopurua : integer;
rZenbatekoa : real;
end;
tardParking = array[1..MAX] of trdAutoarenDatuak;
tfParking = file of trdAutoarenDatuak;
tfGaurkoData = file of trdData; { azterketan ez da eskatzen }
(* ---------------------------- interfazearen amaiera -------------------------- *)
Datu-fitxategien edukia erakusteko. HISTORIKOA.DAT, BEZPERAKOA.DAT eta GARABIA.DAT datu-fitxategien informazioa pantailaratzeko erabiltzen den unitatea. Hauxe da apark unitatearen interfazea:
Dataren eguna hasieratzeko, eskuratzeko, pantailaratzeko eta automatikoki inkrementatzeko unitatea. Data iraunkorki gordetzeko GAURKOEGUNA.DAT fitxategia erabiltzen da, GAURKOEGUNA.DAT fitxategiak trdData datu-motako elementu bakarra dauka. GAURKOEGUNA.DAT fitxategia 2024-06-15 balioarekin sortzen da HISTORIKOA.DAT datu-fitxategiaren sorrerarekin batera; gero, programaren exekuzio bakoitzeko, GAURKOEGUNA.DAT fitxategiak gordetzen duen data egun batez inkrementatzen da. Hauxe da gaur unitatearen interfazea:
{
Data eta ordua automatikoki hartzen direnez, unitate honek data
nola aldatzen den egunez egun simulatzeko balio du. Horretarako,
fitxategi bat erabiltzen da, non 2024-06-15 data gordetzen den
hasieran, eta egunak aurrera joan ahala 2024 urteko egutegia
jarraitzen den.
}
unit gaur;
INTERFACE
uses
konst, motak, crt, sysutils;
procedure prDatarenFitxategiaHasieratu(sFitxIzenGaurkoData: tsKate200);
procedure prDataEskuratu(sFitxIzenGaurkoData: tsKate200; var rdGaurkoData: trdData);
procedure prDataPantailaratu(const rdGaurkoData: trdData);
procedure EgunBatGehiago(const rdGaurkoData: trdData; var rdBiharkoData: trdData);
procedure prDataInkrementatu(sFitxIzenGaurkoData: tsKate200);
(* ---------------------------- interfazearen amaiera -------------------------- *)
Ezaguna denez, Azterketa: 2024ko maiatzaren deialdia izenburuko artikuluan azterkari buruzko informazio guzti-guztia dago. Heltzear den uztaileko deialdiari dagokion programa prestatze aldera, berridatz dezagun maiatzeko programa hori, baina derrigorrezko aginduak nabarmenduz (letra larrietan idatzirik ematen diren aginduak). Ez dugu esan nahi gainerako aginduak soberan daudenik, baizik eta letra larrietan idatziko ditugunak berebiziko garrantzia dutela eta besteak horien menpekoak direla nolabait.
Maiatzeko programan bi datu-fitxategiekin lan egiten da MAHAIAK.DAT dat-fitxategia eta MENUAK.DAT datu-fitxategia. Bi datu-fitxategi horiek aldez aurretik sortuta daude JatetxekoDatuakSortzen.pas programari esker.
2024-05-22_Jatetxea_DerrigorrezkoAginduak.pas fitxategian jasota dagoen maiatzeko programa berezian, letra larriz nabarmendu dira ezinbestekoak diren aginduak. Konpiladorearen ingurune barnetik programa hau exekutatzean, MAHAIAK.DAT datu-fitxategia eta MENUAK.DAT datu-fitxategia C:\Dev-Pas karpetan kokatu behar dira nahitaez. Maiatzeko programa bereziaren kodea jarraian ikusi, non, aurreratu den bezala, azpiprograma bakoitzean letra larrietan jarri diren aginduak garrantzitsutzat jo daitezkeen:
{ Hitz larrietan idatzi diren aginduak funtsezkoenak dira azpiprogrametan, }
{ larrietan dauden aginduen inguruan dabiltzate gainerako agindu guztiak. }
{ Konpiladorearen ingurune barrurik programa hau exekutatzean, MENUAK.DAT eta }
{ MAHAIAK.DAT datu-fitxategiak C:\Dev-Pas karpetan kokatu behar dira. }
program JatetxeaDerrigorrezkoAginduak_2024;
uses
crt, sysutils;
const
iMAHAIEN_MAX = 10;
iMENUEN_MAX = 7;
iAULKI_KOP_MAX = 4;
type
integer = smallint; { INTEGER datu-motek 2 byte hartzera behartzen da }
real = double; { REAL datu-motek 8 byte erabiltzera behartzen da }
tsKate99 = string[99];
tsKate20 = string[20];
trdMahaia = record
iMahaiZbk : integer;
iAulkiKop : integer;
boLibre : boolean;
sErreserbaIzena: tsKate20;
iMahaikideKop : integer;
end;
tfrdMahaiak = file of trdMahaia;
trdMenua = record
sIzena : tsKate20;
rPrezioa : real;
sAsteEguna: tsKate20;
end;
tfrdKarta = file of trdMenua;
tardKarta = array[1..iMENUEN_MAX] of trdMenua;
tarKontua = array[1..iMAHAIEN_MAX] of real;
tfrIrabaziak = file of real;
{----------------Programaren menua------------------}
function fncAukerenMenua: char;
var
cAukera: char;
begin
clrscr;
writeln('AUKEREN MENUA':33);
writeln('=============':33);
writeln('1. ':20, 'Erakutsi jatetxeko mahaien egoera');
writeln('2. ':20, 'Erreserbatu mahaia');
writeln('3. ':20, 'Menuak erakutsi');
writeln('4. ':20, 'Jatekoa eskatu');
writeln('5. ':20, 'Kontua eskatu eta ordaindu');
writeln('0. ':20, 'Programatik irten');
writeln('-----------------':37);
repeat
write('Zure aukera: ':33);
READLN(cAukera); (* KARAKTERE BAT TEKLATUZ IRAKURRI *)
until (cAukera >= '0') and (cAukera <= '5');
FNCAUKERENMENUA := cAukera; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{----------------Asteguna aukeratu------------------}
function fnsAstegunaZehaztu: tsKate20;
var
cAukera: char;
begin
clrscr;
writeln('ASTEGUNAK':29);
writeln('=========':29);
writeln('1. ':20, 'Astelehena');
writeln('2. ':20, 'Asteartea');
writeln('3. ':20, 'Asteazkena');
writeln('4. ':20, 'Osteguna');
writeln('5. ':20, 'Ostirala');
writeln('--------------':34);
repeat
write('Zure aukera: ':33);
READLN(cAukera); (* KARAKTERE BAT TEKLADUZ IRAKURRI *)
until (cAukera >= '1') and (cAukera <= '5');
case cAukera of
'1': FNSASTEGUNAZEHAZTU := 'Astelehena'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'2': FNSASTEGUNAZEHAZTU := 'Asteartea'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'3': FNSASTEGUNAZEHAZTU := 'Asteazkena'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'4': FNSASTEGUNAZEHAZTU := 'Osteguna'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
'5': FNSASTEGUNAZEHAZTU := 'Ostirala'; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
end;
{----------------Menuen fitxategiko datuak arrayan kargatu------------------}
procedure MenuenArrayaKargatuFitxategitik(sFitxIzenMenuak: tsKate99;
sAsteEgunBat: tsKate20;
var ardKarta: tardKarta;
var iLuzera: integer);
var
rdMenuBat: trdMenua;
frdKarta : tfrdKarta;
begin
assign(frdKarta, sFitxIzenMenuak);
reset(frdKarta);
iLuzera := 0;
while not eof(frdKarta) do
begin
READ(frdKarta, rdMenuBat); (* ERREGISTRO BAT FITXATEGITIK IRAKURRI *)
if upcase(rdMenuBat.sAsteEguna) = upcase(sAsteEgunBat) then
begin
iLuzera := iLuzera +1;
ARDKARTA[iLuzera] := rdMenuBat; (* ARRAYAREN ELEMENTU BAT ALDATU *)
end;
end;
close(frdKarta);
end;
{----------------Kontuen arrayak hasieran 0.0 euro posizio guztietan------------------}
procedure KontuenArrayaHasieratu(var arKontua: tarKontua);
var
k: integer;
begin
for k:=1 to iMAHAIEN_MAX do
ARKONTUA[k] := 0.0; (* ARRAYAREN ELEMENTU BAT ALDATU *)
end;
{----------------Mahaien egoera erakutsi------------------}
procedure MahaiakErakutsi(sFitxIzenMahaiak: tsKate99);
var
frdMahaiak: tfrdMahaiak;
rdMahaiBat: trdMahaia;
begin
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
writeln('------------------------------------------------------------------------');
writeln('MAHAIA':10, 'AULKIAK':10, 'MAHAIKIDEAK':15, 'ERABILGARRITASUNA':28);
writeln('------------------------------------------------------------------------');
while not eof(frdMahaiak) do
begin
read(frdMahaiak, rdMahaiBat);
WRITE(rdMahaiBat.iMahaiZbk:10); (* PANTAILAN IDATZI *)
WRITE(rdMahaiBat.iAulkiKop:10); (* PANTAILAN IDATZI *)
WRITE(rdMahaiBat.iMahaikideKop:15); (* PANTAILAN IDATZI *)
if rdMahaiBat.boLibre then
WRITE('Libre':16) (* PANTAILAN IDATZI *)
else
WRITE('Erreserbatua: ':25, rdMahaiBat.sErreserbaIzena); (* PANTAILAN IDATZI *)
writeln;
end;
writeln('------------------------------------------------------------------------');
close(frdMahaiak);
end;
{----------------Mahaia erreserbatu------------------}
procedure MahaiaErreserbatu(sFitxIzenMahaiak: tsKate99;
sBezeroIzena: tsKate20;
iMahaikideak: integer);
var
frdMahaiak : tfrdMahaiak;
rdMahaiBat : trdMahaia;
iAulkiKopurua : integer;
boMahaiaErreserbatua: boolean;
begin
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
boMahaiaErreserbatua := FALSE;
iAulkiKopurua := iMahaikideak;
// Kopuruarekin bat datorren mahai eskuragarria bilatu
repeat
writeln('sBezeroIzena = ', sBezeroIzena, 'iMahaikideak = ':20, iMahaikideak, 'iAulkiKopurua = ':20, iAulkiKopurua);
while not eof(frdMahaiak) and not boMahaiaErreserbatua do
begin
READ(frdMahaiak, rdMahaiBat); (* FITXATEGITIK IRAKURRI *)
if (rdMahaiBat.iAulkiKop = iAulkiKopurua) and rdMahaiBat.boLibre then
begin
rdMahaiBat.boLibre := FALSE;
rdMahaiBat.sErreserbaIzena := sBezeroIzena;
rdMahaiBat.iMahaikideKop := iMahaikideak;
SEEK(frdMahaiak, filepos(frdMahaiak) - 1); (* POSIZIO EGOKIAN KOKATU *)
WRITE(frdMahaiak, rdMahaiBat); (* FITXATEGIAN IDATZI *)
writeln('Erreserba gauzatu da, mahai zenbakia: ':40, rdMahaiBat.iMahaiZbk);
boMahaiaErreserbatua := TRUE;
end
end;
iAulkiKopurua := iAulkiKopurua + 1;
seek(frdMahaiak, 0);
until (iAulkiKopurua > iAULKI_KOP_MAX) or boMahaiaErreserbatua;
if not boMahaiaErreserbatua then
WRITELN('Eskatutako mahaikide kopururako tokirik ez dago.'); (* PANTAILAN IDATZI *)
close(frdMahaiak);
end;
{----------------Menua erakutsi------------------}
procedure EgunekoMenuakPantailaratu(const ardKarta: tardKarta; iLuzera: integer);
var
k: integer;
begin
writeln('--------------------------------------------------------------');
writeln('ZBK.':6, 'MENUA':14, 'PREZIOA':15, 'ASTEGUNA':15);
writeln('--------------------------------------------------------------');
for k:=1 to iLuzera do (* PANTAILAN IDATZI *)
WRITELN(k:5, ardKarta[k].sIzena:15, ardKarta[k].rPrezioa:10:2, ' Euro', ardKarta[k].sAsteEguna:15);
writeln('--------------------------------------------------------------');
end;
{----------------Mandatua------------------}
procedure Mandatua( sFitxIzenMahaiak: tsKate99;
iMahaia: integer;
const ardGaurkoKarta: tardKarta;
iZenbatMenuGaur: integer;
var arKontua: tarKontua);
var
iKont : integer;
frdMahaiak: tfrdMahaiak;
rdMahaiBat: trdMahaia;
iMenuZbk : integer;
begin
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
seek (frdMahaiak, iMahaia-1);
read(frdMahaiak, rdMahaiBat);
close(frdMahaiak);
if rdMahaiBat.iMahaikideKop = 0 then
writeln(iMahaia, '. zenbakidun mahaia libre dago')
else
begin
writeln('Eskatuko den menu kopurua: ',rdMahaiBat.iMahaikideKop);
arKontua[iMahaia] := 0.0; // soberan array hori hasieratuta dagoelako
for iKont:=1 to rdMahaiBat.iMahaikideKop do
begin
repeat
write('Aukeratu ', iKont, '. mahaikidearen menua: ');
READLN(iMenuZbk); (* MENUA AUKERATU *)
until (iMenuZbk >= 1) and (iMenuZbk <= iZenbatMenuGaur);
ARKONTUA[iMahaia] := arKontua[iMahaia] + ardGaurkoKarta[iMenuZbk].rPrezioa;
end; (* KONTUEN ARRAYA EGUNERATU *)
end;
end;
{----------------Ordaindu------------------}
function fnrOrdaindu(const arKontua: tarKontua;
iMahaia: integer): real;
begin
FNRORDAINDU := arKontua[iMahaia]; (* FUNTZIOAK IRTEERAREN BAT IZAN DEZALA *)
end;
{----------------Kontuen arrayaren edukia erakutsi------------------}
procedure KontuenArrayaErakutsi(const arKontua: tarKontua);
var
k: integer;
begin
for k:=1 to iMAHAIEN_MAX do
WRITELN(k:12, '. mahaia: ', ARKONTUA[k]:0:2, ' euro'); (* ARRAYAREN ELEMENTU BAT PANTAILARATU *)
end;
{----------------Ordaindu ondoren mahaia askatu------------------}
procedure MahaiaAskatu(sFitxIzenMahaiak: tsKate99;
iMahaiZenbakia: integer);
var
frdMahaiak: tfrdMahaiak;
rdMahaiBat: trdMahaia;
begin
writeln('Kontua ordaindu ondoren, mahaia libratzen...');
assign(frdMahaiak, sFitxIzenMahaiak);
reset(frdMahaiak);
seek (frdMahaiak, iMahaiZenbakia -1);
read(frdMahaiak, rdMahaiBat);
write('Mahai zenbakia: ', rdMahaiBat.iMahaiZbk);
write('Aulkiak: ':14, rdMahaiBat.iAulkiKop);
write('Mahaikideak: ':18, rdMahaiBat.iMahaikideKop);
write('Bezeroa: ':14, rdMahaiBat.sErreserbaIzena);
writeln;
RDMAHAIBAT.iMahaikideKop := 0; (* MEMORIAN EGUNERATU *)
RDMAHAIBAT.boLibre := TRUE; (* MEMORIAN EGUNERATU *)
RDMAHAIBAT.sErreserbaIzena := ''; (* MEMORIAN EGUNERATU *)
write('Mahai zenbakia: ', rdMahaiBat.iMahaiZbk);
write('Aulkiak: ':14, rdMahaiBat.iAulkiKop);
write('Mahaikideak: ':18, rdMahaiBat.iMahaikideKop);
write('Bezeroa: ':14, rdMahaiBat.sErreserbaIzena);
seek (frdMahaiak, iMahaiZenbakia -1);
WRITE(frdMahaiak, rdMahaiBat); (* FITXATEGIAN EGUNERATU *)
close(frdMahaiak);
end;
{----------------Irabaziak arraytik fitxategira------------------}
procedure IrabaziakGorde(sFitxIzenIrabaziak: tsKate99; const arKontua: tarKontua);
var
frIrabaziak: tfrIrabaziak;
k : integer;
begin
assign(frIrabaziak, sFitxIzenIrabaziak);
rewrite(frIrabaziak);
for k:=1 to iMAHAIEN_MAX do (* MAHAI BAKOITZEKO, ERREPIKATU *)
WRITE(frIrabaziak, arKontua[k]); (* ERREAL BAT FITXATEGIAN GORDE *)
close(frIrabaziak);
end;
{----------------programa nagusia------------------}
var
sFitxIzenMahaiak : tsKate99;
sFitxIzenMenuak : tsKate99;
sFitxIzenIrabaziak: tsKate99;
sAsteEgunBat : tsKate20;
ardGaurkoKarta : tardKarta;
iZenbatMenuGaur : integer;
cAukera : char;
sBezeroIzena : tsKate20;
iMahaikideak : integer;
iMahaia : integer;
arKontua : tarKontua;
begin
clrscr;
writeln('Jatetxeko datuak gordetzen dituzten bi fitxategien izenak zehaztu...');
write('Mahaien fitxategiaren izena eman (adibidez, MAHAIAK.DAT): ');
readln(sFitxIzenMahaiak);
write('Menuen fitxategiaren izena sartu (esaterako, MENUAK.DAT): ');
readln(sFitxIzenMenuak);
if fileexists(sFitxIzenMahaiak) and fileexists(sFitxIzenMenuak) then
begin
write('Gaurko asteguna eman: ');
sAsteEgunBat := fnsAstegunaZehaztu;
MenuenArrayaKargatuFitxategitik(sFitxIzenMenuak, sAsteEgunBat, ardGaurkoKarta, iZenbatMenuGaur);
KontuenArrayaHasieratu(arKontua);
repeat
cAukera := fncAukerenMenua;
clrscr;
case cAukera of
'1': MahaiakErakutsi(sFitxIzenMahaiak);
'2': begin
write('Bezeroaren izena eman: ':40);
readln(sBezeroIzena);
write('Mahaikideen kopurua eman: ':40);
readln(iMahaikideak);
MahaiaErreserbatu(sFitxIzenMahaiak, sBezeroIzena, iMahaikideak);
end;
'3': EgunekoMenuakPantailaratu(ardGaurkoKarta, iZenbatMenuGaur);
'4': begin
repeat
write('Janaria eskatzen, mahaiaren zenbakia eman (1 eta ', iMAHAIEN_MAX, ' artekoa): ');
readln(iMahaia);
until (iMahaia >= 1) and (iMahaia <= iMAHAIEN_MAX);
EgunekoMenuakPantailaratu(ardGaurkoKarta, iZenbatMenuGaur);
Mandatua(sFitxIzenMahaiak, iMahaia, ardGaurkoKarta, iZenbatMenuGaur, arKontua);
writeln;
writeln('Mahai guztien kontuak gordetzen duen arrayaren edukia:');
KontuenArrayaErakutsi(arKontua);
end;
'5': begin
repeat
write('Kontua eskatu duen mahaiaren zenbakia eman (1 eta ', iMAHAIEN_MAX, ' artekoa): ');
readln(iMahaia);
until (iMahaia >= 1) and (iMahaia <= iMAHAIEN_MAX);
if fnrOrdaindu(arKontua, iMahaia) = 0.0 then
writeln(iMahaia, '. zenbakidun mahaia libre dago edo ez da jatekorik eskatu')
else
begin (* MAHAIAK ORDAINDU BEHARREKOA PANTAILARATU *)
WRITELN(iMahaia, ' zenbakiko mahaiak ', fnrOrdaindu(arKontua, iMahaia):0:2, ' Euroko kontua ordaindu behar du.');
MahaiaAskatu(sFitxIzenMahaiak, iMahaia); (* MAHAIA ASKATU *)
end;
end;
'0': begin
sFitxIzenIrabaziak := 'IRABAZIAK_' + sAsteEgunBat + '.DAT';
IrabaziakGorde(sFitxIzenIrabaziak, arKontua);
end;
end;
writeln;
readln;
until cAukera = '0';
end
else (* FITXATEGIREN BAT EZ DENEAN *)
begin
if not fileexists(sFitxIzenMahaiak) then
writeln('ERROREA!! "', sFitxIzenMahaiak, '" fitxategirik ez dago.');
if not fileexists(sFitxIzenMenuak) then
writeln('ERROREA!! "', sFitxIzenMenuak, '" fitxategirik ez dago.');
writeln;
writeln('(RETURN sakatu programatik irteteko)');
readln;
end;
end. (* programaren amaiera *)
Fitxategiaren egitura taula batena da eta bertan agertzen diren zutabeen esanahia jarraian azaltzen da.
Ikaslea identifikatzeko NAN delako lehen zutabea erabiltzen da, zutabe horren arabera ordenaturik dago taula. Laborategiko nota hurrengo lau zutabetan ematen da: 1. KONTROLA (maximoa 10 puntu), LABORATEGIA (maximoa 0,5 puntu), 2. KONTROLA (maximoa 10 puntu) eta LABORATEGIA (maximoa 1 puntu) izenburuko zutabeak. Mintegiko nota banaturik dago PROIEKTUA eta 3. KONTROLA zutabeen artean, bien artean maximoa 1,5 puntu dira eta horien batura MINTEGIA zutabean erakusten da. Taularen azken bi zutabeak batukariak dira (batean maximoa 3 puntu dira, eta bestean 10 puntu dira). Taula ikusi:
Adieraz dezagun orain, irakasgaiaren azken kalifikazioa osatzeko, 1,5+1,5 puntu horiek nola uztartzen diren azterketa idatzian lortutako puntuekin. Horretarako, gogora dezagun aspaldi bateko Irakasgaiaren ebaluazioa blog-artikulua:
Azterketa aurretik 3 puntu lor daitezke ikasturtearen zehar mintegian eta laborategian egindako lanari esker:
Laborategiko 1,5 puntu (1. eta 2. kontrolak)
Mintegiko 1,5 puntu (3. kontrola)
Azterketa idatziak 7 puntu emango dizkio azken notari. Azterketa idatziak bi zati izango ditu (galderak eta programa) banaketa honelakoxea delarik:
Azterketa idatziaren alde teorikoak %30eko pisua izango du, eta ondorioz 2,1 puntu emango dizkio irakasgaiaren azken notari
Azterketa idatziaren programak %70eko pisua izango du, eta ondorioz 4,9 puntu emango dizkio irakasgaiaren azken notari
Irakasgaia gainditu ahal izateko, derrigorrezkoa da azterketa idatziaren erdia egitea, hots, 7 puntuetatik 3,5 puntu lortzea
Deialdi berezian ez dira kontutan hartuko ikasturtearen zehar mintegian eta laborategian egindako lanak. Horregatik, deialdi berezian azterketa idatzian lorturiko emaitza irakasgaiaren kalifikazioa izango da
